;устанавливает автоматическое отображение
;полного имени файла:
; - в заголовке окна NanoCAD
; - в плавающем окне документа
;Файл можно вставить в автозагрузку
  (vl-load-com)

;Тело реактора
(defun set-doc-caption (reactor-object parameter-list / doc app cpt fn path)
  (setq doc (car parameter-list)) ; активируемый документ
  (setq app (vlax-get-acad-object))
  (if (setq cpt (findfile (vla-get-FullName doc)))
    (progn
    (if (= (vla-get-Active doc) :vlax-false) ; плавающее окно
      (setq path "" fn cpt)
      (setq
        path (strcat (vl-filename-directory cpt) "\\")
        fn (strcat (vl-filename-base cpt)  
                   (vl-filename-extension cpt))))
    (vlax-put-property doc 'windowtitle fn)
    (vlax-put-property app 'Caption path)
   ))
  (prin1)
  )

(defun clear-doc-caption (reactor-object parameter-list / )
  (vlax-put-property  (vlax-get-acad-object) 'Caption "")
  (prin1)
  )

;натравливаем ректор на событие

(if (not *EDw_CaptionReactor*)
  (setq *EDw_CaptionReactor* (vlr-docmanager-reactor nil
    '(
    (:vlr-documentBecameCurrent . set-doc-caption)
    (:vlr-documentToBeDeactivated . clear-doc-caption)
    )
    )))
(prin1)