(defun lisp-cs-create-and-proceed-dcl (/ fun_callback file handle dcl_id dcl_res dcl_lst res) ;|
*    Создание dcl-файла и начало работы с ним
*    Параметры вызова:
  нет
*    Возвращает строку фильтрации для ssget либо nil
*    Примеры вызова:
(lisp-cs-create-and-proceed-dcl)
|;
  (defun fun_callback (key value ref-list)
    (set ref-list (subst (cons key value) (assoc key (eval ref-list)) (eval ref-list)))
  ) ;_ end of defun
  (setq file   (strcat (vl-string-right-trim "\\" (getenv "temp")) "\\dlg.dcl")
        handle (open file "w")
  ) ;_ end of setq
  (foreach str '("dlg:dialog{label=\"Фильтр выбора\";fixed_width=true;"
                 "  :row{"                                      "   :column{"
                 "      :toggle{key=\"LINE\";label=\"Отрезки\";width=30;}"
                 "      :toggle{key=\"LWPOLYLINE\";label=\"Полилинии\";width=30;}"
                 "      }"                          "   :column{"
                 "      :toggle{key=\"INSERT\";label=\"Блоки\";width=30;}"
                 "      :toggle{key=\"CIRCLE\";label=\"Окружности\";width=30;}"
                 "      }"                          "   }"
                 "  :row{fixed_width=true;alignment=right;"     "   ok_cancel;"
                 "    }"                                  " }"
                )
    (write-line str handle)
  ) ;_ end of foreach
  (close handle)
  (setq dcl_lst '(("LINE" . "1") ("LWPOLYLINE" . "1") ("INSERT" . "1") ("CIRCLE" . "1")))
  (setq dcl_id (load_dialog file))
  (new_dialog "dlg" dcl_id "(fun_callback $key $value 'dcl_lst)")
  (foreach item dcl_lst (set_tile (car item) (cdr item)))
  (action_tile "accept" "(done_dialog 1)")
  (action_tile "cancel" "(done_dialog 0)")
  (setq dcl_res (start_dialog))
  (unload_dialog dcl_id)
  (if (= dcl_res 1)
    (progn
      (if (setq res (mapcar (function car) (vl-remove-if (function (lambda (x) (= (cdr x) "0"))) dcl_lst)))
        (strcat (car res)
                (apply (function strcat) (mapcar (function (lambda (x) (strcat "," x))) (cdr res)))
        ) ;_ end of strcat
      ) ;_ end of if
    ) ;_ end of progn
  ) ;_ end of if
) ;_ end of defun

(defun c:make-dcl () (lisp-cs-create-and-proceed-dcl))

((lambda () (princ "\nНормальная загрузка") (princ)))

(defun make-fas (/ file prj)
  (if (setq file (findfile (setq prj (strcat "\\\\vmware-host\\Shared Folders\\Share\\make-dcl\\make-dcl"
                                             (itoa (atoi (vl-string-trim "VLISUAP " (strcase (ver)))))
                                             (if (getvar "lispsys")
                                               (strcat "lispsys" (itoa (getvar "lispsys")))
                                               ""
                                             ) ;_ end of if
                                             ".prj"
                                     ) ;_ end of strcat
                           ) ;_ end of setq
                 ) ;_ end of findfile
      ) ;_ end of setq
    (progn (alert (strcat "Сборка " file)) (vlisp-make-project-fas file))
    (alert (strcat "Не найден " prj))
  ) ;_ end of if
) ;_ end of defun